Umu プログラミングガイド

人間：「３と４を足すといくつ？]
計算機：「７です]

<評価(evaluation)> ::= <文> <作用> .

<文(statement)>    ::= <式> | <宣言> .

<作用(effect)>     ::= <値> | <環境> .

umu:1> 3 + 4
val it : Int = 7

<式(expression)> ::=
        <定数>
      | <変数>
      | <適用式>
      | <ラムダ式>
      | <分岐式>
   /* | .... etc */ .

<値(value)> ::=
        <整数>
      | <小数>
      | <文字列>
      | <シンボル>
      | <関数閉包>
   /* | .... etc */ .

umu:1> 3
val it : Int = 3
umu:2> "Apple"
val it : String = "Apple"
umu:3> @Banana
val it : Symbol = @Symbol
umu:4>

<環境(environment)> ::= { <束縛> } .

<束縛(binding)>     ::= <変数> <値> .

<変数(variable)>    ::= <名前> .

umu:1> TRUE
val it : Bool = TRUE
umu:2> Umu::Math::PI
val it : Float = 3.141592653589793
umu:3> (+)
fun it = #<+: { x : Number y : Number -> (x).(+ y) }>
umu:4> foo

[NameError] Unbound value identifier: 'foo' -- #4 in "<stdin>"
umu:5>

<宣言(declaration)> ::=
        <val宣言>
      | <fun宣言>
      | <import宣言>
   /* | .... etc */ .

<val宣言(value declaration)> ::= <変数> <式> .

umu:1> val x = 3        # 変数 x を宣言
val x : Int = 3
umu:2> val y = 4        # 変数 y を宣言
val y : Int = 4
umu:3> val z = x + y    # 式 x + y を評価し、変数 z を宣言
val z : Int = 7
umu:4>

umu:1> 3 + 4
val it : Int = 7
umu:2> (+)
fun it = #<+: { x : Number y : Number -> (x).(+ y) }>
umu:3> it 3
fun it = #<+: { y : Number -> (x).(+ y) }>
umu:4> it 4
val it : Int = 7
umu:5>

<fun 宣言(function declaration)> ::= <関数名> <ラムダ式> .

<関数名(function name)> ::= <変数> .

<ラムダ式(lambda expression)> ::=
        <仮引数(1)> { <仮引数(n)> }  <本体式> .

<仮引数(formal parameter)> ::= <変数> .

<本体式(body expression)> ::= <式> .

<関数閉包(function closure)> ::= <ラムダ式> <環境> .

<適用式(application language)> ::=
        <演算子式> <被演算子式(1)> { <被演算子式(n)> } .

<演算子式(operator expression)>  ::= <式> .

<被演算子式(operand expression)> ::= <式> .

umu:4> fun add = x y -> x + y
fun add = #<add: { x y -> (+ x y) }>
umu:5> val z = add 30 40
val z : Int = 70
umu:6>

人間：「３と４を足すといくつ？]
計算機：「７です]

umu:1> 3 + 4
val it : Int = 7
umu:2> 3 * 4
val it : Int = 12
umu:3> 3.odd?
val it : Bool = TRUE
umu:4> 3.show
val it : String = "3"
umu:5> (+).apply-binary 3 4
val it : Int = 7
umu:6

umu:1> x

[NameError] Unbound value identifier: 'x' -- #1 in "<stdin>"
umu:2> val x = 3
val x : Int = 3
umu:3> x
val it : Int = 3
umu:4>

umu:1> 3.+ 4
val it : Int = 7
umu:2> 3.+
fun it = #<{ %x_1 -> (%r).(+ %x_1) }>
umu:3> it 4
val it : Int = 7
umu:4>

umu:1> (+).apply-binary 3 4
val it : Int = 7
umu:2> (+).apply-binary
fun it = #<{ %x_1 %x_2 -> (%r).(apply-binary %x_1 %x_2) }>
umu:3> it 3
fun it = #<{ %x_2 -> (%r).(apply-binary %x_1 %x_2) }>
umu:4> it 4
val it : Int = 7
umu:5>

<送信式(send expression)> ::=
        <レシーバ式>
        <メッセージ(1)> { <メッセージ(n)> } .

<レシーバ式(receiver expression)> ::= <式> .

<メッセージ(message)> ::=
        <メッセージセレクタ>
        <メッセージ引数(1)> { <メッセージ引数(n)> } .

<メッセージ引数(message parameter)> ::= <式> .

umu:1> :class
Top/
    Class
    Device
    Object/
        Atom/
            Bool
            Number/
                Float
                Int
            String
            Symbol
        Dir
        Fun
        IO/
            Input
            Output
  :
  :
  :
umu:2>

umu:1> [1 .. 10]
val it : Interval = [1 .. 10 (+1)]
umu:2> [1, 3 .. 10]
val it : Interval = [1 .. 10 (+2)]
umu:3> it.contents
val it : Named = (current:1 stop:10 step:2)
umu:4>

umu:1> val add = { x y -> x + y }
fun add = #<{ x y -> (+ x y) }>
umu:2> add 3 4
val it : Int = 7
umu:3>

umu:1> fun add' = x y -> x + y
fun add' = #<add': { x y -> (+ x y) }>
umu:2> add' 3 4
val it : Int = 7
umu:3>

umu:1> fun add'' = (x, y) -> x + y
fun add'' = #<add'': { %a1 : Product
**> %LET { %VAL x = (%a1)$1 %VAL y = (%a1)$2 %IN (+ x y) }
    }>
umu:2> add'' (3, 4)
val it : Int = 7
umu:3>

umu:1> fun rec factorial = x -> (    # 'umu/example/factorial.umu'をコピー＆ペースト
umu:2*     if x <= 1 then
umu:3*         1
umu:4*     else
umu:5*         x * factorial (x - 1)
umu:6* )
fun factorial = #<factorial: { x -> (%IF (<= x 1) %THEN 1 %ELSE (* x (factorial (- x 1)))) }>
umu:7> factorial 3
val it : Int = 6
umu:8>

umu:1> [1, 4, 3, 2]
val it : Cons = [1, 4, 3, 2]
umu:2> [1, 4, 3, 2].sort
val it : Cons = [1, 2, 3, 4]
umu:3> [1, 4, 3, 2].sort.reverse
val it : Cons = [4, 3, 2, 1]
umu:4> [1, 4, 3, 2].sort.reverse.map to-s
val it : Cons = ["4", "3", "2", "1"]
umu:5> [1, 4, 3, 2].sort.reverse.map to-s.join-by "-"
val it : String = "4-3-2-1"
umu:6>

umu:1> [1, 4, 3, 2] |> sort |> reverse |> map to-s |> join-by "-"
val it : String = "4-3-2-1"
umu:2>

umu:1> join-by "-" <| map to-s <| reverse <| sort [1, 4, 3, 2]
val it : String = "4-3-2-1"
umu:2>

umu:1> val f = sort >> reverse >> map to-s >> join-by "-"
fun f = #<{ %x -> (%x |> sort |> reverse |> (map to-s) |> (join-by "-")) }>
umu:2> f [1, 4, 3, 2]
val it : String = "4-3-2-1"
umu:3

umu:1> val f = join-by "-" << map to-s << reverse << sort
fun f = #<{ %x -> (%x |> sort |> reverse |> (map to-s) |> (join-by "-")) }>
umu:2> f [1, 4, 3, 2]
val it : String = "4-3-2-1"
umu:3>

umu:1> join-by "-" (map to-s (reverse (sort [1, 4, 3, 2])))
val it : String = "4-3-2-1"
umu:2>